優太くん公園デビュー - KBDAHOLIC

優太もだいぶ大きくなってきたのでというか多分そろそろ成体なので外に連れ出してみた。そのとき録った動画を物語風にしてみたんだけど土日に子供の DVD 作るおやじみたいな感じになっちゃった。

<a href="http://www.nicovideo.jp/watch/sm3700914">【ニコニコ動画】【ウサギ】公園デビュー【ネザーランドドワーフ】</a>

YouTube にもあげてあるけどニコニコに特化した形式のファイルを上げただけなので画質は悪い。暇な人は探すのもいいかもしれない。

avs ファイルもさらしとくことで後続者を作って子供の DVD ビデオが増えることをもくろむよ！

# park.avs

# 画面のやや下側に文字をセンタリングして入れる関数
# 優太がしゃべってるとおもわれるかんじにする
function Terop(clip clip, string "text", int "start", int "end") {
  SubtitleEx(clip, text, 255, 368, start, end, "くれよん", "c", 22, $00009900, $00ffffff)
}

# 俺がしゃべってるとおもわれるかんじにする
function Terop2(clip clip, string "text", int "start", int "end") {
  SubtitleEx(clip, text, 255, 368, start, end, "S2GP殴り書き", "c", 20, $00000000, $00ffffff)
}

# TrackAxPC で mix 済みの wav を読み込む
WavSource("f.wav")
# 音ズレを直すために開始時間を遅らせる ( 変数 wav に退避 )
wav = DelayAudio(3.7)

# クリップ読み込み
# AviSource だと mjpg の fourcc がないとか言われて読み込めない
clip01 = DirectShowSource("P6010301.avi", audio=false).Trim(60, 0)
clip02 = DirectShowSource("P6010302.avi", audio=false).Trim(300, 0)
clip03 = DirectShowSource("P6010303.avi", audio=false).Trim(0, 840)
clip04 = DirectShowSource("P6010304.avi", audio=false)
clip05 = DirectShowSource("P6010305.avi", audio=false).Trim(80, 0)
clip07 = DirectShowSource("P6010306.avi", audio=false).Trim(810, 0)
clip08 = DirectShowSource("P6010307.avi", audio=false)

# Dissolve で全部つなぐ
Dissolve(clip01, clip02, clip03, clip04, clip05, clip07, clip08, 30)
# 真っ白からフェイドイン
FadeIn(30, $ffffff)
# 真っ白へフェイドアウト ( あとで使うので clip_main という変数へ退避しとく )
clip_main = FadeOut(30, $ffffff)

# 前後にタイトルを書くための真っ白な画を用意する
BlankClip(clip_main, length=60, color=$ffffff)
# 真っ白画には無音の音がついているようなので削る ( 変数 clip_blank に退避 )
clip_blank = KillAudio()

# 真っ白画をメインの前後に結合
clip_blank + clip_main + clip_blank

# WarpSharp 用に YV12 に変換
ConvertToYV12()
# 無駄に Lanczos4
Lanczos4Resize(512, 384)
# 上下に黒帯を追加して (512, 288) にする
Letterbox(48, 48)

# Title
SubtitleEx("ゆうたくんの|こうえんでびゅー", 255, 164, 0, 60, "くれよん", "c", 56, $00009900, $00ffffff)
SubtitleEx("おわり", 255, 192, 2595, 2650, "くれよん", "c", 56, $00009900, $00ffffff)

# ツッコミ
Terop("え、なにいきなり、ここどこ?", 100, 180)
Terop("ちょ、まじ、こうえんとかありえないんですけど", 190, 280)
Terop2("(埒があかないので移動です)", 290, 340)
Terop("たいようがまぶしいぜ", 360, 450)
Terop("しばふうめぇかな?", 470, 520)
Terop("テ　ン　シ　ョ　ン　↑", 550, 600)
Terop("あーでもちょっとまって", 620, 660)
Terop2("(ん…?)", 670, 720)
Terop2("(やっぱり食べてる…、恐ろしい子っ)", 730, 890)
Terop("しばふはさいこーだぜ!!", 900, 1000)
Terop("ふぅ…", 1050, 1120)
Terop("かぜをうけてるおれちょうかっこいい", 1130, 1200)
Terop2("そろそろ移動しますよ?ほら", 1210, 1260)
Terop("ふはは、つかまらんよ", 1270, 1340)
Terop("こ　こ　か　ら　お　れ　の　タ　ー　ン", 1350, 1450)
Terop("ぜぇぜぇ", 1460, 1490)
Terop("ふ　た　た　び　お　れ　の　タ　ー　ン", 1500, 1620)
Terop("はぁはぁ", 1630, 1700)
Terop("ハ　イ　パ　ー　ゆ　う　た　タ　イ　ム", 1710, 1750)
Terop("おそいぜ", 1770, 1850)
Terop("ふぅ…", 1860, 1930)
Terop2("チャンス!!", 1970, 2030)
Terop("まぁおれのかっこよさはいじょうだからな", 2040, 2160)
Terop("え、またいきなり?", 2190, 2300)
Terop("まずい、し　ば　ふ　が　な　い", 2310, 2430)
Terop("しかたない、ねるか", 2440, 2560)

# シャープネス
WarpSharp(128, 3, 128,-0.6)

# FLV のために上下反転
FlipVertical()

# 画と音を結合する
AudioDub(wav)